home *** CD-ROM | disk | FTP | other *** search
/ QRZ! Ham Radio 8 / QRZ Ham Radio Callsign Database - Volume 8.iso / pc / files / dsp / 96000tar.z / 96000tar / 96000 / appb / b115a.asm < prev    next >
Assembly Source File  |  1992-04-28  |  3KB  |  96 lines
  1. ; This program was originally published in the Motorola DSP96002 Users Manual
  2. ; and is provided under a DISCLAIMER OF WARRANTY available from Motorola DSP
  3. ; Operation, 6501 William Cannon Drive West, Austin, Texas 78735-8598.  For
  4. ; more information, refer to the DSP96002 Users Manual, Appendix B, DSP
  5. ; Benchmarks.
  6. ;
  7. ; B.1.15    Fast Fourier Transforms  
  8. ; B.1.15.1    Radix 2 Decimation in Time FFT  
  9. ;metr2a      macro      points,data,coef,coefsize 
  10. ;metr2a      ident      1,4 
  11. ; 
  12. ;Radix 2 Decimation in Time In-Place Fast Fourier Transform Routine 
  13. ; 
  14. ;    Complex input and output data 
  15. ;        Real data in X memory 
  16. ;        Imaginary data in Y memory 
  17. ;    Normally ordered input data 
  18. ;    Bit reversed output data 
  19. ; 
  20. ;    Coefficient lookup table 
  21. ;        +Cosine value (1/2 cycle) in X memory 
  22. ;        +Sine value (1/2 cycle) in Y memory 
  23. ;    Table size can be i*points/2, i=1,2,... 
  24. ; 
  25. ; Macro Call - metr2a   points,data,coef,coefsize 
  26. ; 
  27. ;      points     number of points (2 - 2,147,483,648, power of 2) 
  28. ;      data       start of data buffer 
  29. ;      coef       start of 1/2 cycle sine/cosine table 
  30. ;      coefsize   number of table points in sine/cosine table 
  31. ;                  = i*points/2, i=1,2,...    (1 - 2,147,483,648) 
  32. ; 
  33. ;         
  34. ; ar         Radix 2         ar' 
  35. ; ai        Butterfly        ai' 
  36. ; br        A'=A+B*Wk        br' 
  37. ; bi        B'=A-B*Wk        bi' 
  38. ;       
  39. ;             
  40. ;                    
  41. ;              wr  wi 
  42. ; 
  43. ; wrk = cosine(k*pi/points) table 
  44. ; wik = sine(k*pi/points)   table 
  45. ; 
  46. ; ar' = ar + (wr*br + wi*bi) 
  47. ; ai' = ai + (wr*bi - wi*br) 
  48. ; br' = ar -  wr*br - wi*bi = ar - (wr*br + wi*bi) 
  49. ; bi' = ai -  wr*bi + wi*br = ai - (wr*bi - wi*br) 
  50. ; 
  51.  
  52.       move    #points,d1.l 
  53.       move    #@cvi(@log(points)/@log(2)+0.5),n1 
  54.       move    #data,r2 
  55.       move    #coef,m2 
  56.       move    #coefsize,d2.l 
  57.  
  58.       move    #0,m6 
  59.       move    #-1,m0 
  60.       clr     d0         m0,m1 
  61.       inc     d0         m0,m4 
  62.       lsr     d2         m0,m5 
  63.       move    d2.l,n6 
  64.  
  65.       do      n1,_end_pass 
  66.       move    r2,r0 
  67.       move    d0.l,n2 
  68.       lsr     d1      m2,r6 
  69.       dec     d1      d1.l,n0 
  70.       move    d1.l,n1 
  71.       move    n0,n4 
  72.       move    n0,n5 
  73.       lea     (r0)+n0,r1 
  74.       lea     (r0)-,r4 
  75.       lea     (r1)-,r5 
  76.  
  77.       do      n2,_end_grp 
  78.       move                              x:(r6)+n6,d9.s y:,d8.s 
  79.       move                              x:(r1)+,d6.s   y:,d7.s 
  80.       fmpy.s  d8,d7,d3                                 y:(r5),d2.s 
  81.       fmpy.s  d9,d6,d0                                 y:(r4),d5.s 
  82.       fmpy.s  d9,d7,d1                                 y:(r1),d7.s 
  83.  
  84.       do      n0,_end_bfy 
  85.       fmpy    d8,d6,d2 fadd.s    d3,d0  x:(r0),d4.s    d2.s,y:(r5)+ 
  86.       fmpy    d8,d7,d3 faddsub.s d4,d0  x:(r1)+,d6.s   d5.s,y:(r4)+ 
  87.       fmpy    d9,d6,d0 fsub.s    d1,d2  d0.s,x:(r4)    y:(r0)+,d5.s 
  88.       fmpy    d9,d7,d1 faddsub.s d5,d2  d4.s,x:(r5)    y:(r1),d7.s 
  89. _end_bfy 
  90.       move                              x:(r0)+n0,d7.s d2.s,y:(r5)+n5 
  91.       move                              x:(r1)+n1,d7.s d5.s,y:(r4)+n4 
  92. _end_grp 
  93.       move    n2,d0.l 
  94.       lsl     d0                        n0,d1.l 
  95. _end_pass 
  96.